Wprowadzenie
Przerwania umożliwiają szybkie reagowanie na zdarzenia zewnętrzne bez zbędnego angażowania programu głównego do sprawdzania stanu wybranych układów peryferyjnych. Działanie systemu przerwań opiera się na zbiorze flag, które są ustawiane w chwili wystąpienia danego zdarzenia. Możliwość przerwania sekwencyjnego wykonywania instrukcji programu po wystąpieniu zdarzenia pozwala w znacznie bardziej elastyczny sposób obsługiwać takie zdarzenia programowo. Dla przykładu, gdyby celem było sprawdzanie, czy w timerze wystąpiło przepełnienie lub czy na porcie szeregowym pojawił się nowy znak do odczytu, manualna obsługa wymagałaby wprowadzenia do kodu programu odpowiednich instrukcji testujących, które wykonywane byłyby w każdej iteracji, niezależnie od tego czy zdarzenie faktycznie zaszło, czy nie. Obsługa zdarzenia polega na oddelegowaniu instrukcji wykonywanych po zajściu zdarzenia do procedury obsługi zdarzenia i odblokowaniu przerwania, na które program ma reagować. Każda procedura obsługi przerwania kończy się rozkazem RETI. Szkielet programu obsługującego przerwanie INT1 (zdarzenia na linii P3.3 portu P3) przedstawiono na Listingu 1.
Listing 1 Szkielet programu obsługującego przerwania na INT1
CSEG AT 0
AJMP start ;po resecie wykonujemy skok do początku programu
CSEG AT 13h ;pod adresem 13h z pamięci programu umieszczamy
AJMP Obsluga_int1 ;instrukcję skoku do procedury obsługi przerwania
CSEG AT 30h
start: ;program główny zaczyna się od adresu 30h
;(za tablicą wektorów przerwań)
;Konfiguracja układu przerwań:
SETB IT1 ;przerwanie INT1 aktywowane zboczem
SETB EX1 ;zezwolenie na zewnętrzne przerwanie INT1
SETB EA ;globalne odblokowanie przerwań
loop:
;główna pętla programu
AJMP loop
Obsluga_int1: ;procedura obsługi przerwania
;
;
RETI
END
Zdarzenia, które mogą być obsługiwane przez procedury obsługi przerwań to:
przepełnienie timera 0 (0Bh)
przepełnienie timera 1 (1Bh)
zdarzenie zewnętrzne INT0 (03h)
zdarzenie zewnętrzne INT1 (13h)
znak do odczytu/transmisji na złączu szeregowym (23h)
Adresy wektorów przerwań odpowiadających danym przerwaniom podane są w nawiasach. W przypadku obsługi konkretnego przerwania należy w kodzie programu umieścić instrukcje:
CSEG AT Adres_Wektora
AJMP interruptHandler
gdzie Adres_Wektora to jeden z powyższych adresów, a interrupthandler to procedura obsługi zakończona rozkazem RETI.
Obsługę przerwań konfiguruje się poprzez odpowiednie ustawianie bitów rejestru IE (A8h), co przedstawiono w Tablicy 1.
Tablica 1 Konfiguracja przerwań 8051
Bit |
Nazwa |
Adres |
Funkcja |
7 |
EA |
AFh |
Globalne zablokowanie/odblokowanie przerwań |
6 |
- |
AEh |
Nie używane |
5 |
- |
ADh |
Nie używane |
4 |
ES |
ACh |
Odblokowanie przerwań na porcie szeregowym |
3 |
ET1 |
ABh |
Odblokowanie przerwań na timerze 1 |
2 |
EX1 |
AAh |
Odblokowanie przerwań na INT1 |
1 |
ET0 |
A9h |
Odblokowanie przerwań na timerze 0 |
0 |
EX0 |
A8h |
Odblokowanie przerwań na INT0 |
W sytuacji gdy w trakcie obsługi przerwania dochodzi do zgłoszenia kolejnego przerwania, o kolejności obsługi decyduje priorytet przerwania. Przerwania mogą mieć dwa priorytety - niski i wysoki. Procedura obsługi przerwania o niskim priorytecie może być przerwana przez przerwanie o priorytecie wysokim. Procedura obsługi przerwania o wysokim priorytecie nie może być przerwana przez inne przerwanie. Priorytet przerwań jest konfigurowany przez odpowiednie ustawienie bitów rejestru IP (B8h), zgodnie z Tabelą 2.
Tabela 2 Konfiguracja priorytetów przerwań
Bit |
Nazwa |
Adres |
Funkcja |
7 |
- |
- |
- |
6 |
- |
- |
- |
5 |
- |
- |
- |
4 |
PS |
BCh |
Priorytet przerwania szeregowego |
3 |
PT1 |
BBh |
Priorytet przerwania timera 1 |
2 |
PX1 |
BAh |
Priorytet przerwania INT1 |
1 |
PT0 |
B9h |
Priorytet przerwania timera 0 |
0 |
PX0 |
B8h |
Priorytet przerwania INT0 |
Warto wspomnieć, że flagi przepełnienia timerów należy przy ręcznej obsłudze zerować odpowiednią instrukcją w kodzie programu. W przypadku obsługi wykorzystującej przerwania flagi te są kasowane sprzętowo po przyjęciu obsługi przerwania.
Warto również podać znaczenie pierwszych czterech bajtów rejestru TCON (ostatnie cztery służą do zarządzania timerami, jak to opisano w odpowiednim miejscu). Flagi te opisano w Tabeli 3.
Tabela 3 Pierwsze cztery bity rejestru TCON (88h)
Bit |
Nazwa |
Adres |
Funkcja |
3 |
IE1 |
8Bh |
Znacznik zgłoszenia przerwania zewnętrznego INT1 ustawiany sprzętowo, zerowany przy przyjęciu przerwania |
2 |
IT1 |
8Ah |
Bit określający wyzwalanie przerwania na INT1 poziomem niskim „0” lub zboczem „1” |
1 |
IE0 |
89h |
Znacznik zgłoszenia przerwania zewnętrznego INT0 ustawiany sprzętowo, zerowany przy przyjęciu przerwania |
0 |
IT0 |
88h |
Bit określający wyzwalanie przerwania na INT0 poziomem niskim „0” lub zboczem „1” |
Zadania
Zadanie 1 (dst)
Należy przeanalizować pracę mikrokontrolera poprzez wykonanie symulacji krokowej na podstawie programu przedstawionego na Listingu 1.
Listing 1
CSEG AT 0
AJMP reset
CSEG AT 03h
AJMP INT0service ; skok do procedury obsługi przerwania
; zewnętrznego INT0
CSEG AT 30h
reset:
SETB EX0 ; wlaczenie przerwania INT0
SETB EA ; odblokowanie wszystkich przerwan
loop:
ACALL delay ; przykładowy program główny
CPL P2.7
SJMP loop
INT0service: ; procedura obslugi przerwania INT0
;PUSH ACC ; zapamiętanie akumulatora
;PUSH PSW ; i rejestru stanu
CPL P2.0
;POP PSW
;POP ACC
RETI ; powrót z przerwania
delay:
MOV R0,#100
del2:
MOV R1,#255
del1:
NOP
NOP
DJNZ R1,del1
DJNZ R0,del2
RET
END
a) Proszę sprawdzić działanie programu w symulatorze. Przerwanie należy uaktywnić przez ustawienie 0 na wejściu Pins portu P3 - bit 2. Następnie sprawdzić działanie rzeczywistego układu. W tym przypadku przerwanie jest aktywowane wciśnięciem przycisku S2.
b) Proszę dopisać procedurę obsługi przerwania zewnętrznego INT1 i odpowiednio skonfigurować rejestry kontrolne. Proszę sprawdzić jak będzie wykonywany program:
- w przypadku wystąpienia jednocześnie obu sygnałów przerwań
- podczas wykonywania obsługi przerwania INT0 sygnał przerwania INT1 znika na kilka cykli rozkazowych przed rozkazem RETI obsługi INT0
c) Proszę zmienić priorytet przerwania INT1 na wyższy i sprawdź oba podpunkty pytania b), proszę zamienić priorytety INT0 i INT1 na przeciwne i sprawdzić podpunkty pytania b)
d) Proszę zmienić sposób reakcji na przerwania zewnętrzne tak, aby były one wyzwalane zboczem opadającym.
Zadanie 2 (db)
Należy przeanalizować pracę mikrokontrolera poprzez wykonanie symulacji krokowej na podstawie programu przedstawionego na Listingu 2.
Listing 2
CSEG AT 0
AJMP reset
CSEG AT 30h
reset:
MOV TMOD,#00000010b ; tryb 2 licznik sygnału taktującego
MOV TH0,#-25 ; załadowanie wartości początkowej
SETB TR0 ; podłączenie sygnału do licznika
loop:
ACALL delay ; przykładowy program główny
CPL P2.7
JBC TF0,Przelacz ; sprawdzenie flagi przepełnienia timera
SJMP loop
Przelacz:
CPL P2.0 ; zmiana stanu linii portu na przeciwny
SJMP loop
delay:
MOV R0,#2
del2:
DJNZ R0,del2
RET
END
Proszę podczas symulacji zaobserwować reakcję na wystawienie flagi przepełnienia licznika. Docelowo program ma zmieniać stan wyprowadzenia portu P2.0 w stałych, ściśle określonych interwałach czasowych wyznaczanych przez czasomierz T0. Przy okazji mają być realizowane dodatkowe zadania nie krytyczne w czasie. Czy zmiana stanu P2.0 odbywa się w regularnych chwilach czasowych?
Proszę zmodyfikować program tak, aby w momencie przepełnienia licznika następowało przerwanie, a zmiana stanu P2.0 odbywała się w procedurze jego obsługi.
Zadanie 3 (bdb)
Proszę napisać program, który będzie zliczać sekundy. Liczba sekund ma być prezentowana w postaci binarnej za pomocą diod świecących podłączonych do portu P2.